-- Operator Declarations --
## Cartesian
h1 = 1
h2 = 1
h3 = 1
## Cylindrical
# h2 = 1
# h3 = r
## Spherical
#h2 = r
#h3 = r*sin(theta)
#X = (r, theta, phi)
X = (x, y, z)
W = h1*h2*h3
-- gradient
grad(v) = (d(v,X[1])/h1, d(v,X[2])/h2, d(v,X[3])/h3)
-- divergence
div(v) = ( d(v[1]*h2*h3,X[1]) + d(v[2]*h1*h3, X[2]) + d(v[3]*h1*h2, X[3]) )/W
-- curl
curl(f) = (d(f[3]*h3,X[2]) - d(f[2]*h2,X[3]),
d(f[1]*h1,X[3]) - d(f[3]*h3,X[1]),
d(f[2]*h2,X[1]) - d(f[1]*h1,X[2]))/(h1*h2)
-- laplacian
laplacian(f) = ( d(d(f*h2*h3/h1,X[1]),X[1]) + d(d(f*h1*h3/h2,X[2]),X[2]) + d(d(f*h1*h2/h3,X[3]),X[3]) )/W
-- vector laplacian
vlaplacian(v) = grad(div(v)) - curl(curl(v))
cross(u,v) = (h1*(u[2] v[3] - u[3] v[2]),
h2*(u[3] v[1] - u[1] v[3]),
h3*(u[1] v[2] - u[2] v[1]))/W
"#######################################################"
"# REVERSE ENGINEERING KOIDE's FORMULA #"
"# (c) T. E. Raptis, DAT-NCSR DEMOKRITOS (2013) #"
"# EMAIL: rtheo@dat.demokritos.gr #"
"#######################################################"
"-- Initial Koide Formula Resolved --"
"Assume x:= m_e, y:= m_muon, z:= m_tau"
F = (sqrt(x) + sqrt(y) + sqrt(z))^2 - (3/2)*(x + y + z)
F
"It's Gradient"
simplify(grad(F))
"It's Laplacian"
laplacian(F)
"equivalent to the surface"
q = 2*laplacian(F)*(x*y*z)^(3/2)
"or"
-q*(x*y*z)^3
" "
"Because there is no single integer n: 9 + 2*n|2"
"there is no further exponent of the product xyz"
"that can make all three exponents above integers!"
"This is evidence that the particular surface"
"could have been chosen by a computational structure"
"or a minimization scenario which equals an analog "
"computation (Haken, 1983)"
"http://en.wikipedia.org/wiki/Synergetics_(Haken)"
"http://www.scholarpedia.org/article/Haken-Kelso-Bunz_model"
" "
"-- Hidden Geometric Structure in the Gradient --"
" "
u = sqrt(x/y)
v = sqrt(x/z)
w = sqrt(y/z)
"Let"
u
v
w
"Then"
D = ((0, 1/u, 1/v),
(u, 0, 1/w),
(v, w, 0))
D
"Let"
M = ((0, 1, 1),
(1, 0, 1),
(1, 1, 0))
M
"Taking the product with M"
dot(D,transpose(M))
"Hence diag(D*M)-I/2 = Grad(F)"
"Otherwise: Koide's formula is an integral of the above quantity!"
"D-matrix can be further decomposed into the root of the product"
"of two Generalized Rotations as follows"
" "
"Let {Ra, Rb} two generalized rotations of the form"
Re = ((0, -ex, ey),
(ex, 0, -ez),
(-ey, ez, 0))
Re
Rb = ((0, -bx, by),
(bx, 0, -bz),
(-by, bz, 0))
Rb
"Compare their product with D squared"
dot(Re,Rb)
"D squared"
dot(D,D)
"Let"
ex = sqrt(z)
ey = sqrt(y)
ez = sqrt(x)
Re
bx = 1/sqrt(z)
by = 1/sqrt(y)
bz = 1/sqrt(x)
Rb
"Their product"
dot(Re, Rb)
"Final Formula: D = SQRT(Re*Rb + 4*I). Hence"
"Koide's formula can be seen as the integral of DIAG(SQRT(Re*Rb + 4*I)*M)-I/2"
"Moreover, Re and Rb elements curry over the structure of an exterior product"
"in R^3(cross product)."
"Let"
ve = (ex, ey, ez)
vb = (bx, by, bz)
ve
vb
"Let also, m(i) be the columns of the M matrix. Then"
"ve x vb x m1"
m1 = (0, 1, 1)
Prod1 = cross(ve, cross(vb, m1))
Prod1
"ve x vb x m2"
m2 = (1, 0, 1)
Prod2 = cross(ve, cross(vb, m2))
Prod2
"ve x vb x m3"
m3 = (1, 1, 0)
Prod3 = cross(ve, cross(vb, m3))
Prod3
"Their weighted summand equals the Gradient"
(Prod1 + Prod2 + Prod3)/2
"Hence we simply have the formula"
"Pi*Grad(F) = ve x vb x m1 + ve x vb x m2 + ve x vb x m3 + (3/2)e0"
"e0 being the 'diagonal' vector"
e0 = (1, 1, 1)
e0
"and Pi a permutation matrix"
Pi = ((0, 0, 1),(0, 1, 0),(1, 0 ,0))
Pi
"We again see the 3/2 significance being reflected in the final differential form."
"This significance is perhaps reflected also in the extreme coincidence of this"
"fraction with the 'Perfect Fifth' basis of the ancient Pythagorean Tonal System,"
"(http://en.wikipedia.org/wiki/Pythagorean_tuning)"
"enhancing the view that an unkown computation is hidden behind the particular"
"choice of the Leptonic masses in our universe."
"Last but not least, we discover that our final formula can be recast into the"
"'hydrodynamic' Euler-Clebsch form: "
" "
"Pi*Grad(F) is the sum of Grad(Psi) x Grad(Xi) x Grad(Mi)-(3/2)*e0 "
" "
"after introducing the two potentials"
"Psi"
Psi = (x^(3/2) + y^(3/2) + z^(3/2))*(2/3)
Psi
"Xi"
Xi = 2*(sqrt(x) + sqrt(y)+ sqrt(z))
Xi
"Mi being the columns of the M matrix"